所谓“事出反常必有妖，事由多因必复杂”。对于多因素研究，不仅要关注每个因素的直接效应，还需要考虑因素与因素之间的相互作用。交互作用由于其实际的生物学和专业意义，越来越受到研究者的重视。但由于现实世界事物间联系本身的复杂性，很难穷尽“真实”交互作用的所有形式，目前研究者仍然主要从数据出发，依靠统计学方法进行交互作用的识别，此时称为统计学交互作用（statistical interaction）更为合理。常用的方法包括分层(或亚组)分析后效应的异质性检验、模型中纳入乘积交互项等。同时，根据交互作用的发生机制、模型、效应指标不同，可以分为相加模型和相乘模型两种，其原理各位看官可以查阅相关文献哦。在我们下面的案例中，由于是基于线性模型，通过差值考察效应，实际考察的仅是相加交互作用。

研究效应是研究因素作用下研究对象出现的反应或结果。但从归因的角度来看，不管是多因素研究还是单因素研究，观察到的结果都是多种因素作用产生的综合效应。比如100人用某药后80人有效，有效率80%是综合有效率，需要设置一个不用药且可比对照组，如观察到对照组有效率为60%，实际归因于药物的有效率为20%。因此，研究中归因效应都是通过差异(差或比的形式)体现的。在单因素分析中比较简单，但在多因素分析中，还需要区分主效应、简单效应和交互效应。

主效应是不考虑其他因素存在时，所关注因素不同水平观察结果的差异。比如上例中的20%即为药物的主效应。

简单效应又称单独效应，是指其他因素水平固定时，所关注因素不同水平的效应之差。比如对于重型病人归因于药物有效率为10%(即重型病人用药组有效率65%-对照组55%)。因此简单效应反映的不是所有对象的估计结果，而是某一亚组（如对照组、第1周等）的估计结果。

两个或多个因素间的效应互不独立的情形，即一个因素的单独效应随着另外一个(或多个)因素水平的变化而变化。比如重型病人归因于药物有效率为10%(即重型病人用药组有效率65%-对照组55%)，而轻型病人有效率为30%(即轻型病人用药组有效率95%-对照组65%)，此时即可认为存在了药物与病型存在交互作用。

示例：三组实验（正常、实验A、实验B）治疗某病的效果，进行了21周的随访，随访时点位3、7、14、21周四个时点；Y表示测量指标。

grp：组别。

t：随访时间。

y：测量结果（因变量）。

考虑本研究为重复测量设计，估采用线性混合效应模型（为方便演示，纳入随机效应为随机截距）。

ods html dpi=300 ;

ods graphics / reset height=5in width=7in noborder attrpriority=color ;

proc sgplot data = t;

   styleattrs    datacontrastcolors=("#ff5500" "#4b71af" "#54a767" "#7f72b2" "#d98ac2" "#ccb874" "#ff6b83" "#da8455" "#90b0ed") ;

   vline t /  group=grp response=y stat=mean limits=both limitstat=stddev markers LIMITATTRS=(thickness=1px )

       CLUSTERWIDTH=0.5 datalabel    GROUPDISPLAY=CLUSTER lineattrs=(thickness=3px ) name="a";

   xaxis display=(nolabel)

       valueattrs=(size=9 Family="黑体/Times New Roman" weight=bold)

        labelattrs=(size=10 Family="黑体/Times New Roman" weight=bold)  grid GRIDATTRS=(color=white thickness=1.5) ;

   yaxis  

       valueattrs=(size=9 Family="黑体/Times New Roman" weight=bold)

       label="Y"

        labelattrs=(size=10 Family="黑体/Times New Roman" weight=bold)   grid GRIDATTRS=(color=white thickness=1.5) ;

   keylegend "a"/ title="组别" titleATTRS=( Family="黑体/Times New Roman" size=8 weight=bold) noborder

       VALUEATTRS=( Family="黑体/Times New Roman" size=8 weight=bold) location=inside position=topright down=4;

       format t t. grp grp.;

run;

ods graphics off;

proc means data =t n nmiss mean ;

   var y;

   class grp t;

   format t t. grp grp.;

run;

模型中不纳入交互作用的时，结果即为主效应。

代码：

proc mixed data = t covtest;

  class id grp(ref="1正常") t(ref="3周") /ref=first;

  model y=t grp / solution;

  random int / subject=id type=un solution g ;

  lsmeans t grp /cl diff;

run;

quit;

结果：

（1）模型的固定效应参数估计结果

上图为固定效应的解，模型中没有纳入交互效应，呈现为主效应结果。主效应是基于所有人不分组的结果，此时假设三组随时间的变化趋势线平行。grp结果显示：实验组A与正常组相比，结果低于正常组（实验组A-正常组=-2.4586）。同理，14周和21周结果低于3周结果。

（2）模型的最小二乘均值

上图结果输出模型中组别和时间的最小二乘均值，我们可以发现组间最小二乘均值的差即为模型的系数估计。例如：实验组A-正常组=1.7491-4.2080=2.4589。该结果与上述结果一致。

（3）不同组别的均值

那么我们继续输出均值的结果呢？

proc means data =t n nmiss mean stddev ;

  var y;

  class t ;

  format t t. ;

run;

不同组别的均值结果表明：实验组A-正常组=1.74907-4.20798=-4.4589。此时，我们惊奇地发现，不同组别描述的均值之差和最小二乘均值之差相同，那么这种情况是巧合吗？

在一般情况下，若数据是均衡的，二者的主效应计算结果就是相同；但如果数据不均衡，二者的结果也会不一样。本研究中各测量时点相同，且不存在缺失，可认为是均衡数据。从使用的角度看，若试验是不均衡的，则应该使用LSMEANS。此外，LSMEANS也用于某个因素下水平间差异的检验。小编这里建议大家直接使用LSMEANS。

模型中纳入交互作用的时，结果即为交互效应和简单效应。

代码：

ods output diffs=diffs;

proc mixed data = t covtest;

  class id grp(ref="1正常") t(ref="3周") /ref=first;

  model y=t grp t*grp/ solution;

  random int / subject=id type=un solution g ;

  lsmeans t grp t*grp/cl diff;

run;

quit;

结果：

图中结果表明：时间以“3周”为参照组，组别以“正常”为参照组的情况下，实验组A和正常组比较的估计值为-2.1715，此时的结果即为简单效应，解释为：固定时间=3周时，实验组A与正常组的差值估计。听到这里的小伙伴可能会产生困惑，难道我之前的效应解释都错了？？那让我慢慢道来。首先，通过“lsmeans t grp t*grp/cl diff语句”输出每个分类变量和其交互项的最小二乘均值：

模型输出结果较长，我们通过提取Excel表格，经过筛选结果如下：

结果表明：在控制时间=3周的情况下，实验组A和正常组比较的最小二乘均值的差值为-2.1715。

现在我们再理解下简单效应的概念“其他因素水平固定时，同一因素不同水平的效应之差”。是不是豁然开朗！！！同理，由于本研究为均衡数据，此时控制时间=3周时，实验组A和正常组均值比较的结果仍为-2.1715。

交互结果表明：14周时实验组B与正常组的差值与3周时实验组B与正常组的差值的差值为-1.2483。那么怎么理解这个结果呢？首先，我们得到14周时实验组B与正常组的差值为-1.6624（该结果为组别在时间=14周时的单独效应）。

同理得到3周时实验组B与正常组的差值为-0.4141（该结果为组别在时间=3周时的单独效应）。

那么差值的差值为：-1.6624-（-0.4141）=-1.2483。此刻再理解交互效应的概率“两个或多个因素间的效应互不独立的情形，表示一个因素的单独效应随着另外一个因素水平的变化而变化”，组别在14周的单独效应和组别在3周时的单独效应之差。

现在，可否豁然开朗？

继续！！！

直接上代码：

ods results;

ods output solutionf=EST_bl_y;

proc mixed data=dataset_bl plots=studentpanel(marginal conditional);

  class x(ref="2");

  model y=x logCRP x*logCRP/solution cl;

  lsmeans x/ cl diff;

run;

quit;

其中：

X：定性资料

logCRP：定量资料

y：因变量

此时的Mixed过程步，没有纳入随机效应，结果同线性回归模型结果。

结果显示：logCRP和x存在交互效应。定性资料和定量资料的交互可以理解为：通过定性资料分层，分别拟合模型，模型的系数差，即为交互结果。X分为0 1 2三层分别拟合线性回归模型如下：

此时，我们用X=0时的回归系数减去X=1时的回归系数：0.178-1.275=-1.097。刚好等于模型的估计系数。

那么，是否还有更直观的解释？我们通过绘制不同X分层的回归拟合图，图中的斜率即为X分层建模logCRP的系数。我们发现X=0和X=1具有相同的变化趋势，而X=0、X=1与X=2变化趋势存在交叉，也对应的模型的结果，交互效应具有统计学意义。此时模型还可以解释为：随着logCRP的增加，X=2时具有较快的增长趋势，而X=0和X=1具有相同的增长趋势。听到这里？还不点赞、收藏和转发？？

需要数据和代码的小伙伴私信小编发送“交互”！！！

关注微信公众号，获取更多相关内容！